home *** CD-ROM | disk | FTP | other *** search
/ Cream of the Crop 26 / Cream of the Crop 26.iso / os2 / octa209s.zip / octave-2.09 / libcruft / lapack / zgelss.f < prev    next >
Text File  |  1996-07-19  |  22KB  |  630 lines
  1.       SUBROUTINE ZGELSS( M, N, NRHS, A, LDA, B, LDB, S, RCOND, RANK,
  2.      $                   WORK, LWORK, RWORK, INFO )
  3. *
  4. *  -- LAPACK driver routine (version 2.0) --
  5. *     Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
  6. *     Courant Institute, Argonne National Lab, and Rice University
  7. *     September 30, 1994
  8. *
  9. *     .. Scalar Arguments ..
  10.       INTEGER            INFO, LDA, LDB, LWORK, M, N, NRHS, RANK
  11.       DOUBLE PRECISION   RCOND
  12. *     ..
  13. *     .. Array Arguments ..
  14.       DOUBLE PRECISION   RWORK( * ), S( * )
  15.       COMPLEX*16         A( LDA, * ), B( LDB, * ), WORK( * )
  16. *     ..
  17. *
  18. *  Purpose
  19. *  =======
  20. *
  21. *  ZGELSS computes the minimum norm solution to a complex linear
  22. *  least squares problem:
  23. *
  24. *  Minimize 2-norm(| b - A*x |).
  25. *
  26. *  using the singular value decomposition (SVD) of A. A is an M-by-N
  27. *  matrix which may be rank-deficient.
  28. *
  29. *  Several right hand side vectors b and solution vectors x can be
  30. *  handled in a single call; they are stored as the columns of the
  31. *  M-by-NRHS right hand side matrix B and the N-by-NRHS solution matrix
  32. *  X.
  33. *
  34. *  The effective rank of A is determined by treating as zero those
  35. *  singular values which are less than RCOND times the largest singular
  36. *  value.
  37. *
  38. *  Arguments
  39. *  =========
  40. *
  41. *  M       (input) INTEGER
  42. *          The number of rows of the matrix A. M >= 0.
  43. *
  44. *  N       (input) INTEGER
  45. *          The number of columns of the matrix A. N >= 0.
  46. *
  47. *  NRHS    (input) INTEGER
  48. *          The number of right hand sides, i.e., the number of columns
  49. *          of the matrices B and X. NRHS >= 0.
  50. *
  51. *  A       (input/output) COMPLEX*16 array, dimension (LDA,N)
  52. *          On entry, the M-by-N matrix A.
  53. *          On exit, the first min(m,n) rows of A are overwritten with
  54. *          its right singular vectors, stored rowwise.
  55. *
  56. *  LDA     (input) INTEGER
  57. *          The leading dimension of the array A. LDA >= max(1,M).
  58. *
  59. *  B       (input/output) COMPLEX*16 array, dimension (LDB,NRHS)
  60. *          On entry, the M-by-NRHS right hand side matrix B.
  61. *          On exit, B is overwritten by the N-by-NRHS solution matrix X.
  62. *          If m >= n and RANK = n, the residual sum-of-squares for
  63. *          the solution in the i-th column is given by the sum of
  64. *          squares of elements n+1:m in that column.
  65. *
  66. *  LDB     (input) INTEGER
  67. *          The leading dimension of the array B.  LDB >= max(1,M,N).
  68. *
  69. *  S       (output) DOUBLE PRECISION array, dimension (min(M,N))
  70. *          The singular values of A in decreasing order.
  71. *          The condition number of A in the 2-norm = S(1)/S(min(m,n)).
  72. *
  73. *  RCOND   (input) DOUBLE PRECISION
  74. *          RCOND is used to determine the effective rank of A.
  75. *          Singular values S(i) <= RCOND*S(1) are treated as zero.
  76. *          If RCOND < 0, machine precision is used instead.
  77. *
  78. *  RANK    (output) INTEGER
  79. *          The effective rank of A, i.e., the number of singular values
  80. *          which are greater than RCOND*S(1).
  81. *
  82. *  WORK    (workspace/output) COMPLEX*16 array, dimension (LWORK)
  83. *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
  84. *
  85. *  LWORK   (input) INTEGER
  86. *          The dimension of the array WORK. LWORK >= 1, and also:
  87. *          LWORK >=  2*min(M,N) + max(M,N,NRHS)
  88. *          For good performance, LWORK should generally be larger.
  89. *
  90. *  RWORK   (workspace) DOUBLE PRECISION array, dimension (5*min(M,N)-1)
  91. *
  92. *  INFO    (output) INTEGER
  93. *          = 0:  successful exit
  94. *          < 0:  if INFO = -i, the i-th argument had an illegal value.
  95. *          > 0:  the algorithm for computing the SVD failed to converge;
  96. *                if INFO = i, i off-diagonal elements of an intermediate
  97. *                bidiagonal form did not converge to zero.
  98. *
  99. *  =====================================================================
  100. *
  101. *     .. Parameters ..
  102.       DOUBLE PRECISION   ZERO, ONE
  103.       PARAMETER          ( ZERO = 0.0D0, ONE = 1.0D0 )
  104.       COMPLEX*16         CZERO, CONE
  105.       PARAMETER          ( CZERO = ( 0.0D0, 0.0D0 ),
  106.      $                   CONE = ( 1.0D0, 0.0D0 ) )
  107. *     ..
  108. *     .. Local Scalars ..
  109.       INTEGER            BL, CHUNK, I, IASCL, IBSCL, IE, IL, IRWORK,
  110.      $                   ITAU, ITAUP, ITAUQ, IWORK, LDWORK, MAXMN,
  111.      $                   MAXWRK, MINMN, MINWRK, MM, MNTHR
  112.       DOUBLE PRECISION   ANRM, BIGNUM, BNRM, EPS, SFMIN, SMLNUM, THR
  113. *     ..
  114. *     .. Local Arrays ..
  115.       COMPLEX*16         VDUM( 1 )
  116. *     ..
  117. *     .. External Subroutines ..
  118.       EXTERNAL           DLABAD, DLASCL, DLASET, XERBLA, ZBDSQR, ZCOPY,
  119.      $                   ZDRSCL, ZGEBRD, ZGELQF, ZGEMM, ZGEMV, ZGEQRF,
  120.      $                   ZLACPY, ZLASCL, ZLASET, ZUNGBR, ZUNMBR, ZUNMLQ,
  121.      $                   ZUNMQR
  122. *     ..
  123. *     .. External Functions ..
  124.       INTEGER            ILAENV
  125.       DOUBLE PRECISION   DLAMCH, ZLANGE
  126.       EXTERNAL           ILAENV, DLAMCH, ZLANGE
  127. *     ..
  128. *     .. Intrinsic Functions ..
  129.       INTRINSIC          MAX, MIN
  130. *     ..
  131. *     .. Executable Statements ..
  132. *
  133. *     Test the input arguments
  134. *
  135.       INFO = 0
  136.       MINMN = MIN( M, N )
  137.       MAXMN = MAX( M, N )
  138.       MNTHR = ILAENV( 6, 'ZGELSS', ' ', M, N, NRHS, -1 )
  139.       IF( M.LT.0 ) THEN
  140.          INFO = -1
  141.       ELSE IF( N.LT.0 ) THEN
  142.          INFO = -2
  143.       ELSE IF( NRHS.LT.0 ) THEN
  144.          INFO = -3
  145.       ELSE IF( LDA.LT.MAX( 1, M ) ) THEN
  146.          INFO = -5
  147.       ELSE IF( LDB.LT.MAX( 1, MAXMN ) ) THEN
  148.          INFO = -7
  149.       END IF
  150. *
  151. *     Compute workspace
  152. *      (Note: Comments in the code beginning "Workspace:" describe the
  153. *       minimal amount of workspace needed at that point in the code,
  154. *       as well as the preferred amount for good performance.
  155. *       CWorkspace refers to complex workspace, and RWorkspace refers
  156. *       to real workspace. NB refers to the optimal block size for the
  157. *       immediately following subroutine, as returned by ILAENV.)
  158. *
  159.       MINWRK = 1
  160.       IF( INFO.EQ.0 .AND. LWORK.GE.1 ) THEN
  161.          MAXWRK = 0
  162.          MM = M
  163.          IF( M.GE.N .AND. M.GE.MNTHR ) THEN
  164. *
  165. *           Path 1a - overdetermined, with many more rows than columns
  166. *
  167. *           Space needed for ZBDSQR is BDSPAC = 5*N-1
  168. *
  169.             MM = N
  170.             MAXWRK = MAX( MAXWRK, N+N*ILAENV( 1, 'ZGEQRF', ' ', M, N,
  171.      $               -1, -1 ) )
  172.             MAXWRK = MAX( MAXWRK, N+NRHS*
  173.      $               ILAENV( 1, 'ZUNMQR', 'LT', M, NRHS, N, -1 ) )
  174.          END IF
  175.          IF( M.GE.N ) THEN
  176. *
  177. *           Path 1 - overdetermined or exactly determined
  178. *
  179. *           Space needed for ZBDSQR is BDSPC = 7*N+12
  180. *
  181.             MAXWRK = MAX( MAXWRK, 2*N+( MM+N )*
  182.      $               ILAENV( 1, 'ZGEBRD', ' ', MM, N, -1, -1 ) )
  183.             MAXWRK = MAX( MAXWRK, 2*N+NRHS*
  184.      $               ILAENV( 1, 'ZUNMBR', 'QLC', MM, NRHS, N, -1 ) )
  185.             MAXWRK = MAX( MAXWRK, 2*N+( N-1 )*
  186.      $               ILAENV( 1, 'ZUNGBR', 'P', N, N, N, -1 ) )
  187.             MAXWRK = MAX( MAXWRK, N*NRHS )
  188.             MINWRK = 2*N + MAX( NRHS, M )
  189.          END IF
  190.          IF( N.GT.M ) THEN
  191.             MINWRK = 2*M + MAX( NRHS, N )
  192.             IF( N.GE.MNTHR ) THEN
  193. *
  194. *              Path 2a - underdetermined, with many more columns
  195. *              than rows
  196. *
  197. *              Space needed for ZBDSQR is BDSPAC = 5*M-1
  198. *
  199.                MAXWRK = M + M*ILAENV( 1, 'ZGELQF', ' ', M, N, -1, -1 )
  200.                MAXWRK = MAX( MAXWRK, 3*M+M*M+2*M*
  201.      $                  ILAENV( 1, 'ZGEBRD', ' ', M, M, -1, -1 ) )
  202.                MAXWRK = MAX( MAXWRK, 3*M+M*M+NRHS*
  203.      $                  ILAENV( 1, 'ZUNMBR', 'QLC', M, NRHS, M, -1 ) )
  204.                MAXWRK = MAX( MAXWRK, 3*M+M*M+( M-1 )*
  205.      $                  ILAENV( 1, 'ZUNGBR', 'P', M, M, M, -1 ) )
  206.                IF( NRHS.GT.1 ) THEN
  207.                   MAXWRK = MAX( MAXWRK, M*M+M+M*NRHS )
  208.                ELSE
  209.                   MAXWRK = MAX( MAXWRK, M*M+2*M )
  210.                END IF
  211.                MAXWRK = MAX( MAXWRK, M+NRHS*
  212.      $                  ILAENV( 1, 'ZUNMLQ', 'LT', N, NRHS, M, -1 ) )
  213.             ELSE
  214. *
  215. *              Path 2 - underdetermined
  216. *
  217. *              Space needed for ZBDSQR is BDSPAC = 5*M-1
  218. *
  219.                MAXWRK = 2*M + ( N+M )*ILAENV( 1, 'ZGEBRD', ' ', M, N,
  220.      $                  -1, -1 )
  221.                MAXWRK = MAX( MAXWRK, 2*M+NRHS*
  222.      $                  ILAENV( 1, 'ZUNMBR', 'QLT', M, NRHS, M, -1 ) )
  223.                MAXWRK = MAX( MAXWRK, 2*M+M*
  224.      $                  ILAENV( 1, 'ZUNGBR', 'P', M, N, M, -1 ) )
  225.                MAXWRK = MAX( MAXWRK, N*NRHS )
  226.             END IF
  227.          END IF
  228.          MINWRK = MAX( MINWRK, 1 )
  229.          MAXWRK = MAX( MINWRK, MAXWRK )
  230.          WORK( 1 ) = MAXWRK
  231.       END IF
  232. *
  233.       IF( LWORK.LT.MINWRK )
  234.      $   INFO = -12
  235.       IF( INFO.NE.0 ) THEN
  236.          CALL XERBLA( 'ZGELSS', -INFO )
  237.          RETURN
  238.       END IF
  239. *
  240. *     Quick return if possible
  241. *
  242.       IF( M.EQ.0 .OR. N.EQ.0 ) THEN
  243.          RANK = 0
  244.          RETURN
  245.       END IF
  246. *
  247. *     Get machine parameters
  248. *
  249.       EPS = DLAMCH( 'P' )
  250.       SFMIN = DLAMCH( 'S' )
  251.       SMLNUM = SFMIN / EPS
  252.       BIGNUM = ONE / SMLNUM
  253.       CALL DLABAD( SMLNUM, BIGNUM )
  254. *
  255. *     Scale A if max element outside range [SMLNUM,BIGNUM]
  256. *
  257.       ANRM = ZLANGE( 'M', M, N, A, LDA, RWORK )
  258.       IASCL = 0
  259.       IF( ANRM.GT.ZERO .AND. ANRM.LT.SMLNUM ) THEN
  260. *
  261. *        Scale matrix norm up to SMLNUM
  262. *
  263.          CALL ZLASCL( 'G', 0, 0, ANRM, SMLNUM, M, N, A, LDA, INFO )
  264.          IASCL = 1
  265.       ELSE IF( ANRM.GT.BIGNUM ) THEN
  266. *
  267. *        Scale matrix norm down to BIGNUM
  268. *
  269.          CALL ZLASCL( 'G', 0, 0, ANRM, BIGNUM, M, N, A, LDA, INFO )
  270.          IASCL = 2
  271.       ELSE IF( ANRM.EQ.ZERO ) THEN
  272. *
  273. *        Matrix all zero. Return zero solution.
  274. *
  275.          CALL ZLASET( 'F', MAX( M, N ), NRHS, CZERO, CZERO, B, LDB )
  276.          CALL DLASET( 'F', MINMN, 1, ZERO, ZERO, S, MINMN )
  277.          RANK = 0
  278.          GO TO 70
  279.       END IF
  280. *
  281. *     Scale B if max element outside range [SMLNUM,BIGNUM]
  282. *
  283.       BNRM = ZLANGE( 'M', M, NRHS, B, LDB, RWORK )
  284.       IBSCL = 0
  285.       IF( BNRM.GT.ZERO .AND. BNRM.LT.SMLNUM ) THEN
  286. *
  287. *        Scale matrix norm up to SMLNUM
  288. *
  289.          CALL ZLASCL( 'G', 0, 0, BNRM, SMLNUM, M, NRHS, B, LDB, INFO )
  290.          IBSCL = 1
  291.       ELSE IF( BNRM.GT.BIGNUM ) THEN
  292. *
  293. *        Scale matrix norm down to BIGNUM
  294. *
  295.          CALL ZLASCL( 'G', 0, 0, BNRM, BIGNUM, M, NRHS, B, LDB, INFO )
  296.          IBSCL = 2
  297.       END IF
  298. *
  299. *     Overdetermined case
  300. *
  301.       IF( M.GE.N ) THEN
  302. *
  303. *        Path 1 - overdetermined or exactly determined
  304. *
  305.          MM = M
  306.          IF( M.GE.MNTHR ) THEN
  307. *
  308. *           Path 1a - overdetermined, with many more rows than columns
  309. *
  310.             MM = N
  311.             ITAU = 1
  312.             IWORK = ITAU + N
  313. *
  314. *           Compute A=Q*R
  315. *           (CWorkspace: need 2*N, prefer N+N*NB)
  316. *           (RWorkspace: none)
  317. *
  318.             CALL ZGEQRF( M, N, A, LDA, WORK( ITAU ), WORK( IWORK ),
  319.      $                   LWORK-IWORK+1, INFO )
  320. *
  321. *           Multiply B by transpose(Q)
  322. *           (CWorkspace: need N+NRHS, prefer N+NRHS*NB)
  323. *           (RWorkspace: none)
  324. *
  325.             CALL ZUNMQR( 'L', 'C', M, NRHS, N, A, LDA, WORK( ITAU ), B,
  326.      $                   LDB, WORK( IWORK ), LWORK-IWORK+1, INFO )
  327. *
  328. *           Zero out below R
  329. *
  330.             IF( N.GT.1 )
  331.      $         CALL ZLASET( 'L', N-1, N-1, CZERO, CZERO, A( 2, 1 ),
  332.      $                      LDA )
  333.          END IF
  334. *
  335.          IE = 1
  336.          ITAUQ = 1
  337.          ITAUP = ITAUQ + N
  338.          IWORK = ITAUP + N
  339. *
  340. *        Bidiagonalize R in A
  341. *        (CWorkspace: need 2*N+MM, prefer 2*N+(MM+N)*NB)
  342. *        (RWorkspace: need N)
  343. *
  344.          CALL ZGEBRD( MM, N, A, LDA, S, RWORK( IE ), WORK( ITAUQ ),
  345.      $                WORK( ITAUP ), WORK( IWORK ), LWORK-IWORK+1,
  346.      $                INFO )
  347. *
  348. *        Multiply B by transpose of left bidiagonalizing vectors of R
  349. *        (CWorkspace: need 2*N+NRHS, prefer 2*N+NRHS*NB)
  350. *        (RWorkspace: none)
  351. *
  352.          CALL ZUNMBR( 'Q', 'L', 'C', MM, NRHS, N, A, LDA, WORK( ITAUQ ),
  353.      $                B, LDB, WORK( IWORK ), LWORK-IWORK+1, INFO )
  354. *
  355. *        Generate right bidiagonalizing vectors of R in A
  356. *        (CWorkspace: need 3*N-1, prefer 2*N+(N-1)*NB)
  357. *        (RWorkspace: none)
  358. *
  359.          CALL ZUNGBR( 'P', N, N, N, A, LDA, WORK( ITAUP ),
  360.      $                WORK( IWORK ), LWORK-IWORK+1, INFO )
  361.          IRWORK = IE + N
  362. *
  363. *        Perform bidiagonal QR iteration
  364. *          multiply B by transpose of left singular vectors
  365. *          compute right singular vectors in A
  366. *        (CWorkspace: none)
  367. *        (RWorkspace: need BDSPAC)
  368. *
  369.          CALL ZBDSQR( 'U', N, N, 0, NRHS, S, RWORK( IE ), A, LDA, VDUM,
  370.      $                1, B, LDB, RWORK( IRWORK ), INFO )
  371.          IF( INFO.NE.0 )
  372.      $      GO TO 70
  373. *
  374. *        Multiply B by reciprocals of singular values
  375. *
  376.          THR = MAX( RCOND*S( 1 ), SFMIN )
  377.          IF( RCOND.LT.ZERO )
  378.      $      THR = MAX( EPS*S( 1 ), SFMIN )
  379.          RANK = 0
  380.          DO 10 I = 1, N
  381.             IF( S( I ).GT.THR ) THEN
  382.                CALL ZDRSCL( NRHS, S( I ), B( I, 1 ), LDB )
  383.                RANK = RANK + 1
  384.             ELSE
  385.                CALL ZLASET( 'F', 1, NRHS, CZERO, CZERO, B( I, 1 ), LDB )
  386.             END IF
  387.    10    CONTINUE
  388. *
  389. *        Multiply B by right singular vectors
  390. *        (CWorkspace: need N, prefer N*NRHS)
  391. *        (RWorkspace: none)
  392. *
  393.          IF( LWORK.GE.LDB*NRHS .AND. NRHS.GT.1 ) THEN
  394.             CALL ZGEMM( 'C', 'N', N, NRHS, N, CONE, A, LDA, B, LDB,
  395.      $                  CZERO, WORK, LDB )
  396.             CALL ZLACPY( 'G', N, NRHS, WORK, LDB, B, LDB )
  397.          ELSE IF( NRHS.GT.1 ) THEN
  398.             CHUNK = LWORK / N
  399.             DO 20 I = 1, NRHS, CHUNK
  400.                BL = MIN( NRHS-I+1, CHUNK )
  401.                CALL ZGEMM( 'C', 'N', N, BL, N, CONE, A, LDA, B, LDB,
  402.      $                     CZERO, WORK, N )
  403.                CALL ZLACPY( 'G', N, BL, WORK, N, B, LDB )
  404.    20       CONTINUE
  405.          ELSE
  406.             CALL ZGEMV( 'C', N, N, CONE, A, LDA, B, 1, CZERO, WORK, 1 )
  407.             CALL ZCOPY( N, WORK, 1, B, 1 )
  408.          END IF
  409. *
  410.       ELSE IF( N.GE.MNTHR .AND. LWORK.GE.3*M+M*M+MAX( M, NRHS, N-2*M ) )
  411.      $          THEN
  412. *
  413. *        Underdetermined case, M much less than N
  414. *
  415. *        Path 2a - underdetermined, with many more columns than rows
  416. *        and sufficient workspace for an efficient algorithm
  417. *
  418.          LDWORK = M
  419.          IF( LWORK.GE.3*M+M*LDA+MAX( M, NRHS, N-2*M ) )
  420.      $      LDWORK = LDA
  421.          ITAU = 1
  422.          IWORK = M + 1
  423. *
  424. *        Compute A=L*Q
  425. *        (CWorkspace: need 2*M, prefer M+M*NB)
  426. *        (RWorkspace: none)
  427. *
  428.          CALL ZGELQF( M, N, A, LDA, WORK( ITAU ), WORK( IWORK ),
  429.      $                LWORK-IWORK+1, INFO )
  430.          IL = IWORK
  431. *
  432. *        Copy L to WORK(IL), zeroing out above it
  433. *
  434.          CALL ZLACPY( 'L', M, M, A, LDA, WORK( IL ), LDWORK )
  435.          CALL ZLASET( 'U', M-1, M-1, CZERO, CZERO, WORK( IL+LDWORK ),
  436.      $                LDWORK )
  437.          IE = 1
  438.          ITAUQ = IL + LDWORK*M
  439.          ITAUP = ITAUQ + M
  440.          IWORK = ITAUP + M
  441. *
  442. *        Bidiagonalize L in WORK(IL)
  443. *        (CWorkspace: need M*M+4*M, prefer M*M+3*M+2*M*NB)
  444. *        (RWorkspace: need M)
  445. *
  446.          CALL ZGEBRD( M, M, WORK( IL ), LDWORK, S, RWORK( IE ),
  447.      $                WORK( ITAUQ ), WORK( ITAUP ), WORK( IWORK ),
  448.      $                LWORK-IWORK+1, INFO )
  449. *
  450. *        Multiply B by transpose of left bidiagonalizing vectors of L
  451. *        (CWorkspace: need M*M+3*M+NRHS, prefer M*M+3*M+NRHS*NB)
  452. *        (RWorkspace: none)
  453. *
  454.          CALL ZUNMBR( 'Q', 'L', 'C', M, NRHS, M, WORK( IL ), LDWORK,
  455.      $                WORK( ITAUQ ), B, LDB, WORK( IWORK ),
  456.      $                LWORK-IWORK+1, INFO )
  457. *
  458. *        Generate right bidiagonalizing vectors of R in WORK(IL)
  459. *        (CWorkspace: need M*M+4*M-1, prefer M*M+3*M+(M-1)*NB)
  460. *        (RWorkspace: none)
  461. *
  462.          CALL ZUNGBR( 'P', M, M, M, WORK( IL ), LDWORK, WORK( ITAUP ),
  463.      $                WORK( IWORK ), LWORK-IWORK+1, INFO )
  464.          IRWORK = IE + M
  465. *
  466. *        Perform bidiagonal QR iteration, computing right singular
  467. *        vectors of L in WORK(IL) and multiplying B by transpose of
  468. *        left singular vectors
  469. *        (CWorkspace: need M*M)
  470. *        (RWorkspace: need BDSPAC)
  471. *
  472.          CALL ZBDSQR( 'U', M, M, 0, NRHS, S, RWORK( IE ), WORK( IL ),
  473.      $                LDWORK, A, LDA, B, LDB, RWORK( IRWORK ), INFO )
  474.          IF( INFO.NE.0 )
  475.      $      GO TO 70
  476. *
  477. *        Multiply B by reciprocals of singular values
  478. *
  479.          THR = MAX( RCOND*S( 1 ), SFMIN )
  480.          IF( RCOND.LT.ZERO )
  481.      $      THR = MAX( EPS*S( 1 ), SFMIN )
  482.          RANK = 0
  483.          DO 30 I = 1, M
  484.             IF( S( I ).GT.THR ) THEN
  485.                CALL ZDRSCL( NRHS, S( I ), B( I, 1 ), LDB )
  486.                RANK = RANK + 1
  487.             ELSE
  488.                CALL ZLASET( 'F', 1, NRHS, CZERO, CZERO, B( I, 1 ), LDB )
  489.             END IF
  490.    30    CONTINUE
  491.          IWORK = IL + M*LDWORK
  492. *
  493. *        Multiply B by right singular vectors of L in WORK(IL)
  494. *        (CWorkspace: need M*M+2*M, prefer M*M+M+M*NRHS)
  495. *        (RWorkspace: none)
  496. *
  497.          IF( LWORK.GE.LDB*NRHS+IWORK-1 .AND. NRHS.GT.1 ) THEN
  498.             CALL ZGEMM( 'C', 'N', M, NRHS, M, CONE, WORK( IL ), LDWORK,
  499.      $                  B, LDB, CZERO, WORK( IWORK ), LDB )
  500.             CALL ZLACPY( 'G', M, NRHS, WORK( IWORK ), LDB, B, LDB )
  501.          ELSE IF( NRHS.GT.1 ) THEN
  502.             CHUNK = ( LWORK-IWORK+1 ) / M
  503.             DO 40 I = 1, NRHS, CHUNK
  504.                BL = MIN( NRHS-I+1, CHUNK )
  505.                CALL ZGEMM( 'C', 'N', M, BL, M, CONE, WORK( IL ), LDWORK,
  506.      $                     B( 1, I ), LDB, CZERO, WORK( IWORK ), N )
  507.                CALL ZLACPY( 'G', M, BL, WORK( IWORK ), N, B, LDB )
  508.    40       CONTINUE
  509.          ELSE
  510.             CALL ZGEMV( 'C', M, M, CONE, WORK( IL ), LDWORK, B( 1, 1 ),
  511.      $                  1, CZERO, WORK( IWORK ), 1 )
  512.             CALL ZCOPY( M, WORK( IWORK ), 1, B( 1, 1 ), 1 )
  513.          END IF
  514. *
  515. *        Zero out below first M rows of B
  516. *
  517.          CALL ZLASET( 'F', N-M, NRHS, CZERO, CZERO, B( M+1, 1 ), LDB )
  518.          IWORK = ITAU + M
  519. *
  520. *        Multiply transpose(Q) by B
  521. *        (CWorkspace: need M+NRHS, prefer M+NHRS*NB)
  522. *        (RWorkspace: none)
  523. *
  524.          CALL ZUNMLQ( 'L', 'C', N, NRHS, M, A, LDA, WORK( ITAU ), B,
  525.      $                LDB, WORK( IWORK ), LWORK-IWORK+1, INFO )
  526. *
  527.       ELSE
  528. *
  529. *        Path 2 - remaining underdetermined cases
  530. *
  531.          IE = 1
  532.          ITAUQ = 1
  533.          ITAUP = ITAUQ + M
  534.          IWORK = ITAUP + M
  535. *
  536. *        Bidiagonalize A
  537. *        (CWorkspace: need 3*M, prefer 2*M+(M+N)*NB)
  538. *        (RWorkspace: need N)
  539. *
  540.          CALL ZGEBRD( M, N, A, LDA, S, RWORK( IE ), WORK( ITAUQ ),
  541.      $                WORK( ITAUP ), WORK( IWORK ), LWORK-IWORK+1,
  542.      $                INFO )
  543. *
  544. *        Multiply B by transpose of left bidiagonalizing vectors
  545. *        (CWorkspace: need 2*M+NRHS, prefer 2*M+NRHS*NB)
  546. *        (RWorkspace: none)
  547. *
  548.          CALL ZUNMBR( 'Q', 'L', 'C', M, NRHS, N, A, LDA, WORK( ITAUQ ),
  549.      $                B, LDB, WORK( IWORK ), LWORK-IWORK+1, INFO )
  550. *
  551. *        Generate right bidiagonalizing vectors in A
  552. *        (CWorkspace: need 3*M, prefer 2*M+M*NB)
  553. *        (RWorkspace: none)
  554. *
  555.          CALL ZUNGBR( 'P', M, N, M, A, LDA, WORK( ITAUP ),
  556.      $                WORK( IWORK ), LWORK-IWORK+1, INFO )
  557.          IRWORK = IE + M
  558. *
  559. *        Perform bidiagonal QR iteration,
  560. *           computing right singular vectors of A in A and
  561. *           multiplying B by transpose of left singular vectors
  562. *        (CWorkspace: none)
  563. *        (RWorkspace: need BDSPAC)
  564. *
  565.          CALL ZBDSQR( 'L', M, N, 0, NRHS, S, RWORK( IE ), A, LDA, VDUM,
  566.      $                1, B, LDB, RWORK( IRWORK ), INFO )
  567.          IF( INFO.NE.0 )
  568.      $      GO TO 70
  569. *
  570. *        Multiply B by reciprocals of singular values
  571. *
  572.          THR = MAX( RCOND*S( 1 ), SFMIN )
  573.          IF( RCOND.LT.ZERO )
  574.      $      THR = MAX( EPS*S( 1 ), SFMIN )
  575.          RANK = 0
  576.          DO 50 I = 1, M
  577.             IF( S( I ).GT.THR ) THEN
  578.                CALL ZDRSCL( NRHS, S( I ), B( I, 1 ), LDB )
  579.                RANK = RANK + 1
  580.             ELSE
  581.                CALL ZLASET( 'F', 1, NRHS, CZERO, CZERO, B( I, 1 ), LDB )
  582.             END IF
  583.    50    CONTINUE
  584. *
  585. *        Multiply B by right singular vectors of A
  586. *        (CWorkspace: need N, prefer N*NRHS)
  587. *        (RWorkspace: none)
  588. *
  589.          IF( LWORK.GE.LDB*NRHS .AND. NRHS.GT.1 ) THEN
  590.             CALL ZGEMM( 'C', 'N', N, NRHS, M, CONE, A, LDA, B, LDB,
  591.      $                  CZERO, WORK, LDB )
  592.             CALL ZLACPY( 'G', N, NRHS, WORK, LDB, B, LDB )
  593.          ELSE IF( NRHS.GT.1 ) THEN
  594.             CHUNK = LWORK / N
  595.             DO 60 I = 1, NRHS, CHUNK
  596.                BL = MIN( NRHS-I+1, CHUNK )
  597.                CALL ZGEMM( 'C', 'N', N, BL, M, CONE, A, LDA, B( 1, I ),
  598.      $                     LDB, CZERO, WORK, N )
  599.                CALL ZLACPY( 'F', N, BL, WORK, N, B( 1, I ), LDB )
  600.    60       CONTINUE
  601.          ELSE
  602.             CALL ZGEMV( 'C', M, N, CONE, A, LDA, B, 1, CZERO, WORK, 1 )
  603.             CALL ZCOPY( N, WORK, 1, B, 1 )
  604.          END IF
  605.       END IF
  606. *
  607. *     Undo scaling
  608. *
  609.       IF( IASCL.EQ.1 ) THEN
  610.          CALL ZLASCL( 'G', 0, 0, ANRM, SMLNUM, N, NRHS, B, LDB, INFO )
  611.          CALL DLASCL( 'G', 0, 0, SMLNUM, ANRM, MINMN, 1, S, MINMN,
  612.      $                INFO )
  613.       ELSE IF( IASCL.EQ.2 ) THEN
  614.          CALL ZLASCL( 'G', 0, 0, ANRM, BIGNUM, N, NRHS, B, LDB, INFO )
  615.          CALL DLASCL( 'G', 0, 0, BIGNUM, ANRM, MINMN, 1, S, MINMN,
  616.      $                INFO )
  617.       END IF
  618.       IF( IBSCL.EQ.1 ) THEN
  619.          CALL ZLASCL( 'G', 0, 0, SMLNUM, BNRM, N, NRHS, B, LDB, INFO )
  620.       ELSE IF( IBSCL.EQ.2 ) THEN
  621.          CALL ZLASCL( 'G', 0, 0, BIGNUM, BNRM, N, NRHS, B, LDB, INFO )
  622.       END IF
  623.    70 CONTINUE
  624.       WORK( 1 ) = MAXWRK
  625.       RETURN
  626. *
  627. *     End of ZGELSS
  628. *
  629.       END
  630.